マイクロコンピュータH8/3048におけるタイマ割り込み

01Feb2004
12Nov2002
Copyright(C) TNCT CS Kosaka

【１】　はじめに
この文書ではタイマ割り込みに関して説明している。

【２】一般的なタイマ割り込みの仕組み
　H8CPU内部には「タイマユニット」があり，その中にはシステムクロックをカウントアップするカウンタと，設定された値を保持しているレジスタがあり，この2つの値が一致することによって割り込み要求信号を発生している。割り込み要求信号が発生すると同時にカウンタはリセットされるため，割り込み要求信号は周期的に発生することになる。（発生した割り込み要求信号は割り込み処理手続きの中で消さなければならない。）タイマユニットがこのような動作をするためには事前にこのような動作をするように設定が必要である。
　CPUが割り込み許可状態で，割り込み要求信号を受け取ると，タイマ割り込み処理が始まる。
　タイマ割り込みが生ずると，メモリアドレスの先頭付近に置かれた割り込みベクタテーブル（割り込みが起こったらどのアドレスにジャンプするかのアドレス表）中から，タイマ割り込みの時に参照するベクタ（具体的には割り込み関数の先頭アドレス）を取り出し，そのアドレスにジャンプする。（正確には，CCR[コンディションコードレジスタ]と現在のPC[プログラムカウンタ]を退避させてから，割り込み関数呼び出しする）

割り込み関数は，次の作業を行なわなければならない。

（１）はじめに各レジスタの値をスタックに退避する
（２）タイマユニットの割り込みフラッグをクリアする（割り込み作業が開始したことを知らせ，割り込み要求を取り下げさせる）
（３）必要な作業を行なう
（４）各レジスタにスタックから退避させた値を復帰する
（５）割り込みリターンする（通常の関数では関数リターンだが，CCR[コンディションコードレジスタ]の復帰も行なう）

　次のプログラムはタイマ割り込みを用いてLEDのON-OFFを行う。アセンブリ言語で書かれたものである。
割り込み要因はタイマユニットITU0を用いている。

　通常の電源ONの起動時には０番地に書いてあるアドレスから始まる。すなわち（A)RES_STRから処理が始まる。そのあと変数や必要な設定レジスタを設定し，処理は（B)の無限ループとなる。

割り込みは10msecごとに起動し，次のように動作する。
（１）0x60番地に割り込み関数のアドレス_int_imia0が書いてある。割り込みが生じたら_int_imia0へ処理が移る。
 これはリンカスクリプトにかかれている。
　この時次の4つのことが自動的に行なわれている。
　a)CCR（[コンディションコードレジスタ）をスタック領域にPUSHする
　b)CCRの割り込みマスクをセットし，割り込み禁止になる
　c)現在のPC（プログラムカウンタ）の値をスタック領域にPUSHする。あとで関数から戻るときに使う。
　d)PCにITU_IMIA0のアドレスを書き込む
（２）PUSH　使用レジスタの値をスタックに退避する
（３）タイマユニットの割り込みフラッグをクリアする（割り込み作業が終了したことを知らせ，割り込み要求を取り下げさせる）
（４）必要な作業（LEDのON-OFFなど）を行なう
（５）POP　スタックに退避させた値をレジスタに復帰する
（６）RTE　割り込みリターンする（通常の関数では関数リターンRTSが使われるここではRTE)
　この時次のことが行なわれる。
　a)（１）c)で退避したもとのアドレスをスタックからPCに復帰する。割り込み前の作業が継続される
　b)（１）a)で退避したCCR（コンディションコードレジスタ）の復帰。割り込みが許可された状態に戻る

inttest.S

  


/*--------------------------------------------------------
 割り込みテスト inttest.S
 01Feb2004 coskx
--------------------------------------------------------*/
    .h8300h

    .section .text
    .global _start
    .global _int_imia0

    .equ    ITU_TSTR,   0xFFFF60   /*ITU TSTR*/
    .equ    ITU0_TCR,   0xFFFF64   /*ITUch0 TCR*/
    .equ    ITU0_TIER,  0xFFFF66   /*ITUch0 TIER*/
    .equ    ITU0_TSR,   0xFFFF67   /*ITUch0 TSR*/
    .equ    ITU0_GRA,   0xFFFF6A   /*ITUch0 GRA*/
    .equ    P5_DDR,     0xFFFFC8
    .equ    P5_DR,      0xFFFFCA

    .section .bss
    .align 2
    .comm    LOOP,   2
    .comm    TICK,   2

    .section .text
    .align 2

/**************** MAIN PROGRAM **************************/

_start:
    /*スタックポインタの初期化*/
    mov.l   #0xFFFF00,er7      /*Set Stack Pointer*/
    mov.b   #0b00100011,r0l    /*Initialize ITU0_TCR*/
                               /*GRAcomparematch+Clock/8*/
    mov.b   r0l,@ITU0_TCR:8
    bclr    #0,@ITU0_TSR:8     /*Clear IMFA*/
    mov.b   #0b00000001,r0l    /*Initialize ITU0_TIER*/
    mov.b   r0l,@ITU0_TIER:8
    mov.w   #19999,r0          /*Initialize ITU0_GRA*/
                               /*Period=10msec*/
    mov.w   r0,@ITU0_GRA
    mov.b   #0b00000011,r0l    /*Initialize P5_DDR (initLED)*/
    mov.b   r0l,@P5_DDR:8

    mov.w   #0,r0              /*Clear variables*/
    mov.w   r0,@LOOP           /*    LOOP=0*/
    mov.w   r0,@TICK           /*    TICK=0*/
    bset    r0l,@ITU_TSTR:8    /*Start ITU ch0*/

    andc    #0x7f,ccr    /*Clear Interrupt mask*/
EternalLoop:
    bra EternalLoop

/**************** IMIA0 INTERRUPT FUNCTION ******************/
_int_imia0:
    PUSH.L  er0
    BCLR    #0,@ITU0_TSR:8     /* Clear Interrupt Flag    */
    MOV.W   @TICK,r0           /*    if (TICK==1) {       */
    CMP.W   #1:16,r0
    BNE     ELSE1
IF1:
        MOV.B   #1:8,r0l       /*        P5.DR=1          */
        MOV.B   r0l,@P5_DR:8
        BRA     ENDIF1
ELSE1:                         /*    } else {             */
        MOV.B   #2:8,r0l       /*        P5.DR=2          */
        MOV.B   r0l,@P5_DR:8
ENDIF1:                        /*    }                    */
    MOV.W   @LOOP,r0           /*    LOOP++               */
    INC.W   #1,r0
    MOV.W   r0,@LOOP
    CMP.W   #50:16,r0          /*    if (LOOP==50) {      */
    BNE     ENDIF2
IF2:
        MOV.W   #1:16,e0       /*       TICK=1-TICK       */
        MOV.W   @TICK,r0
        SUB.W   r0,e0
        MOV.W   e0,@TICK
        SUB.W   r0,r0          /*       LOOP=0            */
        MOV.W   r0,@LOOP
ENDIF2:                        /*    }                    */
    POP.L   er0
    RTE

    .end
































（A)





















（B)



（２）
（３）
（４）
























（５）
（６）

 

ここまでの説明をまとめると次のようになる

（１）タイマ割り込みの準備

CPU

 　 タイマユニット
    mov.b   #0b00100011,r0l    /*Initialize ITU0_TCR*/
                               /*GRAcomparematch+Clock/8*/
    mov.b   r0l,@ITU0_TCR:8
    bclr    #0,@ITU0_TSR:8     /*Clear IMFA*/
    mov.b   #0b00000001,r0l    /*Initialize ITU0_TIER*/
    mov.b   r0l,@ITU0_TIER:8
    mov.w   #19999,r0          /*Initialize ITU0_GRA*/
                               /*Period=10msec*/
    mov.w   r0,@ITU0_GRA
ITU（タイマユニット）さん，10msecごとに割り込みを入れてね
 → 　了解

    bset    r0l,@ITU_TSTR:8    /*Start ITU ch0*/

ITU（タイマユニット）さん，動作を開始してください
 → 　了解

    andc    #0x7f,ccr    /*Clear Interrupt mask*/

私が割り込みを受け付けられるようにします
 　 　

（２）タイマ割り込みの動作

CPU

 　

タイマユニット
割り込み要求信号

了解

 ←

時間ですよ

割り込みの受け付け（次の動作を自動的に行なう）

a)CCR（[コンディションコードレジスタ）をスタック領域にPUSHする　*1
b)CCRの割り込みマスクをセットし，割り込み禁止になる
　　　「私が割り込みを受け付けられない状態になります。」
c)現在のPC（プログラムカウンタ）の値をスタック領域にPUSHする。あとで関数から戻るときに使う。　*2
d)PCにITU_IMIA0のアドレスを書き込む
　　　「割り込み関数にジャンプすることになります」

 　

時間ですよ
を言い続ける
↓

割り込み関数の開始

    PUSH.L  er0

割り込み関数中で使用するレジスタをスタックに退避します。
 　

時間ですよ
を言い続ける
↓

    BCLR    #0,@ITU0_TSR:8     /* Clear Interrupt Flag    */

ITU（タイマユニット）さん，「時間ですよ」を了解しました。もう言わなくてもOKです。
　*3		 → 了解。黙ります。

    MOV.W   @TICK,r0           /*    if (TICK==1) {       */
    CMP.W   #1:16,r0
    BNE     ELSE1
IF1:
        MOV.B   #1:8,r0l       /*        P5.DR=1          */
        MOV.B   r0l,@P5_DR:8
        BRA     ENDIF1
ELSE1:                         /*    } else {             */
        MOV.B   #2:8,r0l       /*        P5.DR=2          */
        MOV.B   r0l,@P5_DR:8
ENDIF1:                        /*    }                    */
    MOV.W   @LOOP,r0           /*    LOOP++               */
    INC.W   #1,r0
    MOV.W   r0,@LOOP
    CMP.W   #50:16,r0          /*    if (LOOP==50) {      */
    BNE     ENDIF2
IF2:
        MOV.W   #1:16,e0       /*       TICK=1-TICK       */
        MOV.W   @TICK,r0
        SUB.W   r0,e0
        MOV.W   e0,@TICK
        SUB.W   r0,r0          /*       LOOP=0            */
        MOV.W   r0,@LOOP
ENDIF2:                        /*    }                    */

P5.DRを操作してLEDのON-OFFの作業を行ないます。
ここが割り込みルーチンの作業本体
 　 　

    POP.L   er0

スタックに退避していたレジスタ値をレジスタに復帰します。
 　 　

    RTE

*2で退避したもとのアドレスをスタックからPCに復帰する。割り込み前の作業に戻る。
*1で退避したCCR（コンディションコードレジスタ）の復帰。割り込みが許可された状態に戻る。
　　　　「私は次の割り込みを受け付けることが出来ます」

割り込み関数の動作終了		 　 　

*3 タイマユニットに対して割り込み要求を取り下げさせる。この作業を忘れると割り込み関数が終了直後に，再び割り込みを受け付けて，割り込み関数が起動してしまう。

 

【３】　タイマ割り込みの仕掛け

ここで解説するタイマ割り込みの記述方法は汎用性を持つものであるが，「GCC」の記述規則に依存するものである。

タイマ割り込み関数の名前を　「_int_imia1」　とする。（この名前はリンカスクリプトで決まっている）

（１）割り込みベクタ　0X60　に　「_int_imia1」　の先頭アドレスを書いておく。（割り込みベクタは4バイトである。）
この記述はリンカスクリプトに書いてある。

リンカスクリプト
LONG(DEFINED(_int_imia1)?ABSOLUTE(_int_imia1):ABSOLUTE(_start))

 

（２）割り込み関数であることを示すために「#pragma interrupt」宣言を行なうと，コンパイラが自動的に次の処理を付け加えてくれる。

前処理
　　　１）各レジスタの値をスタックに退避する

後処理
　　　６）各レジスタにスタックから退避させた値を復帰する
　　　７）割り込みリターンする

（３）残されたことは，割り込み関数　「_int_imia1」　には次のことを記述すればよい。

１）実行したい内容
２）タイマユニットの割り込みフラッグをクリア

割り込み関数の例

#pragma interrupt   /*次の名前の関数は割り込みルーチン仕様である*/
                    /*プログラム中から呼び出してはならない*/
void int_imia1()
{
    static int tick=0;
    if (tick==1) {
        turnOnLed(0);
        turnOffLed(1);
    } else {
        turnOffLed(0);
        turnOnLed(1);
    }
    tick=1-tick;
    ITU1.TSR.BIT.IMFA=0; /*Clear IMFA*/
}


なおタイマ割り込みが起こった時の処理は次のようになる。

時間の経過 割り込みベクタ 割り込み関数
int_imia1
　 0x60にint_imia1 　
　↓ 　 レジスタ退避（この部分はコンパイラが作ってくれる）
　↓ 　 タイマ割り込みで実行したい内容
割り込み要因解除
　↓ 　 レジスタ復帰（この部分はコンパイラが作ってくれる）
割り込みルーチンリターン（この部分はコンパイラが作ってくれる）


【４】　タイマ割り込みの起動
プログラムの起動時にh8-01.h中にある「タイマ割り込み初期化関数」と「CPUの割り込み許可関数E_INT()」を呼び，「タイマ起動関数」を呼ぶと，「タイマ割り込み初期化関数」で設定した時間間隔でタイマ割り込みが起こり，「割り込み関数int_imia1() 」が周期的に起動するようになる。

なお「タイマ割り込み初期化関数」と「タイマ起動関数」は2組あり，組み合わせを崩してはならない。
（１）短周期割り込み（ITU1による割り込み）

タイマ割り込み初期化関数

 void initTimer1Int(unsigned short int period)

意味

 ITU1による割り込みタイマーの設定
 割り込み間隔は引数peiodで単位はμsecである
 値は32767以下でなければならない。32.767msecまで設定可能
割り込み要因はIMIA1信号である

タイマ起動関数

 void startTimer1(void)

意味

 Timer CH1 スタート

（２）長周期割り込み（ITU0とITU1の両方を使用した割り込み）

タイマ割り込み初期化関数

 void initTimer01Int(unsigned short int period)

意味

ITU0とITU1による割り込みタイマーの設定
（ITU0のオーバーフローを利用したITU1の割り込み）
 割り込み間隔は引数peiodで単位はmsecである
 値は65535以下でなければならない。65.535secまで設定可能
 ただしポートPAの第3ビットが使用できなくなるので注意
割り込み要因はIMIA1信号である

タイマ起動関数

 void startTimer01(void)

意味

 Timer CH0 CH1 同時スタート

 

【５】　「#pragma interrupt」の役割の検証

「#pragma interrupt」の役割をテストプログラムで見てみよう。
このCソースプログラムで関数「testfunc1()」と関数「testfunc2()」は作業は同じだが，関数「testfunc1()」は割り込み関数であると宣言されている。

Ｃソースプログラム

int a=0;

#pragma interrupt
void testfunc1()
{
    a++;
}

void testfunc2()
{
    a++;
}


コンパイラが生成したａｓｍソースでみると，関数「testfunc1()」では，関数の初めに利用しているレジスタの退避コードがあり，関数の終わりにレジスタの復帰コードが生成されている。さらに関数の終わりは，関数「testfunc1()」では，「RTE」（ReTurn from Exception）で終了し，関数「testfunc2()」では，「RTS」（ReTurn from Subroutine）で終了しているのが分る。
er6のpushとpopはGCCの都合によるもの。

コンパイラが生成したａｓｍソース

_testfunc1:
    mov.l er6,@-er7
    mov.l er7,er6
    mov.l er2,@-er7
    mov.w @_a,r2
    adds #1,er2
    mov.w r2,@_a
    mov.l @er7+,er2
    mov.l @er7+,er6
    rte

_testfunc2:
    mov.l er6,@-er7
    mov.l er7,er6
    mov.w @_a,r2
    adds #1,er2
    mov.w r2,@_a
    mov.l @er7+,er6
    rts
=push er6

=push er2



=pop er2
=pop er6



=push er6




=pop er6