//grobe-SCD30_Co2_sensor.ino

#include <M5Stack.h>
#include <SparkFun_SCD30_Arduino_Library.h>
#include <Wire.h>

#define CO2_CALIBRATION_FACTOR 400  // CO2 concentration in fresh outdoor air (ppm)
#define TEMPERATURE_OFFSET_MAX 999  // tempreture offset 0..999 (0.0 .. 99.9 deg)
#define OFFSET_WORK_DURATION 1000
#define SCD30_WORK_INTERVAL 5 //5sec

SCD30 scd30;

int tempoffset_deg=0; //decidegree

void setup()
{
  Serial.begin(115200);
  M5.begin();
  M5.Power.begin();
  M5.Lcd.fillScreen(TFT_BLACK);
  M5.Lcd.setCursor(0, 0);
  M5.Lcd.setTextColor(TFT_WHITE, TFT_BLACK);
  M5.Lcd.setTextSize(3);
  M5.Lcd.println("   // SCD 30 //");
  M5.Lcd.println("SCD30 setup...");
  Serial.println("// SCD 30 //");
  Serial.println("SCD30 setup...");
  Wire.begin();
  if (scd30.begin() == false) {
    Serial.println("fail!");
    Serial.println("SCD30 not detected. You should check wiring. Freezing...");
    M5.Lcd.println("fail!");
    M5.Lcd.setTextSize(2);
    M5.Lcd.println("SCD30 not detected. You should check wiring. Freezing...");
    while (1);
  }
  M5.Lcd.println("\r\ncompleted");
  Serial.println("completed");
  tempoffset_deg = (int)(scd30.getTemperatureOffset()*10.0);
  scd30.setMeasurementInterval(SCD30_WORK_INTERVAL); //stored in non-volatile memory of SCD30
  delay(2000);
  instructions();
  workOnTempOffset();
}

void instructions()
{
  M5.Lcd.setTextSize(2);
  M5.Lcd.setCursor(0, 5 * 24 + 4);
  M5.Lcd.println("Expose the CO2 sensor to\r\nfresh outdoor air for 5\r\nmin before calibrating it.\r\n");
  M5.Lcd.println("buttonA: calibrate sensor");
  M5.Lcd.println("buttonB: TempOffset -0.1");
  M5.Lcd.println("buttonC: TempOffset +0.1");
}

void workOnTempOffset()
{
  float tmpofs =(float)tempoffset_deg/10.0;
  scd30.setTemperatureOffset(tmpofs); //stored in non-volatile memory of SCD30
  M5.Lcd.setTextColor(TFT_WHITE, TFT_BLACK);
  M5.Lcd.setCursor(0, 4 * 24 + 4);
  M5.Lcd.setTextSize(2);
  M5.Lcd.printf("TempOffset %4.1f deg\n", tmpofs);
  Serial.printf("TempOffset %4.1f deg\n", tmpofs);
}

void displayDatas()
{
  uint16_t co2_ppm;
  float temperature_degc;
  float humidity_pct;
  float tmpofs =(float)tempoffset_deg/10.0;

  // get sensor datas
  co2_ppm = scd30.getCO2();
  temperature_degc = scd30.getTemperature();
  humidity_pct = scd30.getHumidity();

  Serial.print("co2(ppm):");
  Serial.print(co2_ppm);
  Serial.print(" temp(degC):");
  Serial.print(temperature_degc, 1);
  Serial.print(" humidity(%):");
  Serial.print(humidity_pct, 1);
  Serial.print(" tempoffs(deg):");
  Serial.println(tmpofs, 1);

  M5.Lcd.setCursor(0, 1 * 24);
  M5.Lcd.setTextSize(3);
  M5.Lcd.setTextColor(TFT_YELLOW, TFT_BLACK);
  M5.Lcd.printf("CO2   %4d ppm\n", co2_ppm);
  M5.Lcd.printf("Temp  %4.1f degC\n", temperature_degc);
  M5.Lcd.printf("Humid %4.1f %%\n", humidity_pct);
}

void loop()
{
  M5.update();
  if (M5.BtnA.wasReleased()) {
    scd30.setForcedRecalibrationFactor(CO2_CALIBRATION_FACTOR);
    delay(3000);
  } else if (M5.BtnB.wasReleased()) {
    tempoffset_deg--;
    if (tempoffset_deg < 0) tempoffset_deg = 0;
    workOnTempOffset();
  } else if (M5.BtnC.wasReleased()) {
    tempoffset_deg++;
    if (TEMPERATURE_OFFSET_MAX < tempoffset_deg) tempoffset_deg = TEMPERATURE_OFFSET_MAX;
    workOnTempOffset();
  }
  if (scd30.dataAvailable()) {
    displayDatas();
  }
}