//DistanceSenSor_TripleVL53l0xTrial0.ino//

#include <M5Stack.h>
#include <Wire.h>
#include "VL53L0Xm1.h"

//https://github.com/pololu/vl53l0x-arduino
//https://klab.hateblo.jp/entry/2021/04/18/094705
//3つのVL53L0Xを同時に使いますが，defaultでは3つとも同じI2Cアドレス0x29を持っています。
//アドレスの競合を避けるために，2台目センサのアドレスを0x2bに，3台目センサのアドレスを0x2dに変更します。
//VL53L0XにはXSHUTという端子があり，これをLにするとそのVL53L0Xは無効になります。
//この仕組みを利用して1台目センサと2台目センサを無効にしておいて，そのすきに3台目センサと通信してI2Cアドレスを変更します。
//次に1台目センサを無効にしておいて，そのすきに2台目センサと通信してI2Cアドレスを変更します。
//GPIO26を1台目センサのXSHUTに接続しておきます。
//GPIO19を1台目センサのXSHUTに接続しておきます。
//
//1台目と2台目センサのXSHUTをLにすると，defaultアドレスで有効なのは3台目センサだけになります。
//この状況で3台目センサのアドレス変更作業を行います。
//この作業が終わったら，2台目センサのXSHUTおHに戻して2台目センサを復活させます。
//この状況で，defaultアドレスで有効なのは3台目センサだけになります。
//この状況で2台目センサのアドレス変更作業を行います。
//この作業が終わったら，1台目センサのXSHUTおHに戻して1台目センサを復活させます。
//ここで，VL53L0XのXSHUTは2.8V信号で，2.8Vでプルアップされているため，XSHUTがつながっているGPIO26はOpenDrain設定にしておく必要があります。
//しかし，ノイズ低減のため，通常出力に設定します。
//
//M5Stackがresetボタンでリセットされたとき，更新プログラムが書き込まれたとき，VL53L0Xはリセットされないので，
//書き換えられているセンサのI2Cアドレスは書き換わったままになります。
//この状態になったとき困るのは3台目のセンサのみです。
//その場合は，先に
//justsetAddress()
//を行なって，クラスインスタンス内のI2Cアドレスのみ変更します。

//SingleMode   (not ContinuousMode)
//必要なときに1回だけ測距

VL53L0X sensor1;
VL53L0X sensor2;
VL53L0X sensor3;

int measurementstatus1 = 0; //0:何もしていない　1:リクエスト中
int measurementstatus2 = 0; //0:何もしていない　1:リクエスト中
int measurementstatus3 = 0; //0:何もしていない　1:リクエスト中

const int SDApin = 21; //SDAピン番号
const int SCLpin = 22; //SCLピン番号

const int XSHUTofSensor1pin = 26; //1台目センサのXSHUTのピン番号
const int XSHUTofSensor2pin = 19; //1台目センサのXSHUTのピン番号
const uint8_t Sensor2I2Caddress = 0x2b; //変更後の2台目センサのI2Cアドレス
const uint8_t Sensor3I2Caddress = 0x2d; //変更後の3台目センサのI2Cアドレス

void checkI2CAddress() {
  int address, error;
  //見つかったaddressの対になるadrressは+0x80にある
  for (address = 1; address<128; address++) {
    Wire.beginTransmission(address);
    error = Wire.endTransmission();
    if(error==0){
      M5.Lcd.print(address,HEX);M5.Lcd.print(" ");
    }
    delay(1);
  }
  M5.Lcd.println();  
}

void setup()
{
  M5.begin();
  M5.Power.begin();
  M5.Lcd.setTextSize(2); //高さ16　26文字/行

  //pinMode(XSHUTofSensor1pin, OUTPUT_OPEN_DRAIN);//オープンドレイン設定
  //pinMode(XSHUTofSensor2pin, OUTPUT_OPEN_DRAIN);//オープンドレイン設定
  pinMode(XSHUTofSensor1pin, OUTPUT);//通常出力設定　ノイズ誤動作軽減
  pinMode(XSHUTofSensor2pin, OUTPUT);//通常出力設定　ノイズ誤動作軽減
  digitalWrite(XSHUTofSensor1pin, LOW); //1台目センサを無効状態にする
  digitalWrite(XSHUTofSensor2pin, LOW); //2台目センサを無効状態にする
  delay(1000); //無効状態＝初期化を確実にする

  Wire.begin(SDApin,SCLpin); //ここをGray用に設定しないと通信に失敗する
  Wire.setClock(400000); // use 400 kHz I2C

  M5.Lcd.setCursor(0, 100);
  //I2Cアドレス使用状況の検証
  checkI2CAddress();
  
  Wire.beginTransmission(Sensor3I2Caddress);
  if (Wire.endTransmission()==0) { //3台目センサが前回設定のアドレスを覚えていたとき
    sensor3.setTimeout(500); //[msec]
    sensor3.justsetAddress(Sensor3I2Caddress);
    if (!sensor3.init())
    {
      M5.Lcd.println("Sensor3 not reinitialized");
      while (1);
    }
    M5.Lcd.println("Sensor3 reinitialized");
  } else {
    sensor3.setTimeout(500); //[msec]
    if (!sensor3.init())
    {
      M5.Lcd.println("Sensor3 not initialized");
      if (sensor3.timeoutOccurred()) M5.Lcd.println("Time out");
      while (1);
    }
    sensor3.setAddress((uint8_t)Sensor3I2Caddress); //3台目センサーのアドレス変更
    M5.Lcd.println("Sensor3 initialized");
  }

  digitalWrite(XSHUTofSensor2pin, HIGH); //2台目センサを有効状態に戻す

  sensor2.setTimeout(500); //[msec]
  if (!sensor2.init())
  {
    M5.Lcd.println("Sensor2 not initialized");
    while (1);
  }
  sensor2.setAddress((uint8_t)Sensor2I2Caddress); //2台目センサーのアドレス変更
  M5.Lcd.println("Sensor2 initialized");

  digitalWrite(XSHUTofSensor1pin, HIGH); //1台目センサを有効状態に戻す

  //checkI2CAddress();

  sensor1.setTimeout(500); //[msec]
  if (!sensor1.init())
  {
    M5.Lcd.println("Sensor1 not initialized");
    while (1);
  }
  M5.Lcd.println("Sensor1 initialized");

  //I2Cアドレス使用状況の検証
  checkI2CAddress();

  sensor1.setMeasurementTimingBudget(50000); //測定タイミングバジェット(1回の距離測定)に許容される時間[micros]
  sensor2.setMeasurementTimingBudget(50000); //測定タイミングバジェット(1回の距離測定)に許容される時間[micros]
  sensor3.setMeasurementTimingBudget(50000); //測定タイミングバジェット(1回の距離測定)に許容される時間[micros]
  M5.Lcd.setCursor(0, 0);
  M5.Lcd.println("Triple VL53L0X Started");
}

void loop()
{
  if (measurementstatus1 == 0) {
    sensor1.requestSingle(); //start the measurement
    measurementstatus1 = 1;
  } else if (sensor1.timeoutOccurred()) {
    M5.Lcd.setCursor(0, 30);
    M5.Lcd.print("Sensor1 TIMEOUT         ");
    measurementstatus1 = 0;
  } else if (measurementstatus1 == 1) {
    if (sensor1.dataReady()){ //センサデータ取得完了だったら
      measurementstatus1 = 0;
      int result = 0;
      result = sensor1.readSingle();
      M5.Lcd.setCursor(0, 30);
      M5.Lcd.print("                        ");
      M5.Lcd.setCursor(0, 30);
      M5.Lcd.printf("S1 result[mm]:%5d  \n",result);
    }
  }
  if (measurementstatus2 == 0) {
    sensor2.requestSingle(); //start the measurement
    measurementstatus2 = 1;
  } else if (sensor2.timeoutOccurred()) {
      M5.Lcd.setCursor(0, 50);
      M5.Lcd.print("Sensor2 TIMEOUT         ");
      measurementstatus2 = 0;
  } else if (measurementstatus2 == 1) {
    if (sensor2.dataReady()){ //センサデータ取得完了だったら
      measurementstatus2 = 0;
      int result = 0;
      result = sensor2.readSingle();
      M5.Lcd.setCursor(0, 50);
      M5.Lcd.print("                        ");
      M5.Lcd.setCursor(0, 50);
      M5.Lcd.printf("S2 result[mm]:%5d  \n",result);
    }
  }
  if (measurementstatus3 == 0) {
    sensor3.requestSingle(); //start the measurement
    measurementstatus3 = 1;
  } else if (sensor3.timeoutOccurred()) {
      M5.Lcd.setCursor(0, 70);
      M5.Lcd.print("Sensor3 TIMEOUT         ");
      measurementstatus3 = 0;
  } else if (measurementstatus3 == 1) {
    if (sensor2.dataReady()){ //センサデータ取得完了だったら
      measurementstatus3 = 0;
      int result = 0;
      result = sensor3.readSingle();
      M5.Lcd.setCursor(0, 70);
      M5.Lcd.print("                        ");
      M5.Lcd.setCursor(0, 70);
      M5.Lcd.printf("S3 result[mm]:%5d  \n",result);
    }
  }
}