XIAO ESP32S3とWinPCでBLE Uart通信

ボードライブラリ「ESP32 by Espressif Systems Ver3.3.6」ではBLE関連のライブラリが動作不調になりましたが，「ESP32 by Espressif Systems Ver3.3.7」で解消されました。
これによって，標準ライブラリのBLEが舞台裏でNimBLEに変更されています。
20260218

温度センサBMP280を載せたWi-FiマイコンXIAO ESP32S3からWindowsパソコンに向けてBLE(Bluetooth Low Energy)を使って温度情報を送ります。
Wi-FiマイコンとWindowsパソコン間の通信は無線LAN環境の下ではHTTPでの通信ができますが，無線LAN環境がない場合では，Bluetooth通信が便利です。
XIAO ESP32S3はBLE UART Profileを使って通信します。（Bluetooth Classicではありません。）

BLEコネクション通信では，Central(or Master or Observer)とPeripheral(or Slave or Broadcaster)の間で通信が行われます。
ここでは，WindowsPCをCentral，XIAO-ESP32S3をPeripheralとして使うことにします。
（PeripheralはServer，CentralはClientと説明されることもあります。）

なお，ここで使用するWindowsPCのアプリ"BLE_serial_terminal"は起動の度に，通信相手を探して接続するようになっているため，ペアリングを必要としていません。（Peripheral側がペアリング・ボンディングを要求する設定になっている場合は，Central側の通信アプリが接続動作の際にCentral側の設定機構がペアリング・ボンディングを行ないます。）

３．１　ArduinoIDE

(1)Arduino IDEのメニューバーから[ファイルFile] -> [環境設定(Preferences)]
Additional board manager URLsに
https://files.seeedstudio.com/arduino/package_seeeduino_boards_index.json
および
https://raw.githubusercontent.com/espressif/arduino-esp32/gh-pages/package_esp32_index.json
を設定してOK
(2)ツール[Tools] > ボード[Board] > Boards Manager
検索boxに「ESP」を入力すると複数のボード候補が出てくるので
esp32 by Espressif Systems
をinstall
(3)ツール[Tools] > ボード[Board]でESP32を探すとXIAO ESP32S3が見つかるので，これを選ぶ。

３．２　XIAO ESP32S3

XIAO ESP32S3の説明書を読んでプログラムの転送方法を確認します。
（USBケーブルでつないで書き込むだけでした。）

（BLE Uart通信のテストだけならBMP280は使用しないので，ここは読み飛ばしてください）

温度センサBMP280は温度をデジタル値に変換しているので，そのデータをXIAO ESP32S3が読み出します。
XIAO ESP32S3と温度センサBMP280はI2C接続ですので，電源線，GND線の他はSCLとSDAの2本のみで通信できます。

CSBをVCCにつなぐとBMP280はI2C接続になります。（データシートによれば確実にVCCにつなぐべきとなっています）
SDO(シルク印刷は間違えていてSDDとなっている)をVCCにつなぐとBMP280のI2Cアドレスは77になります。GNDにつなぐとBMP280のI2Cアドレスは76になります。Groveライブラリのデフォルトは77なのでVCCにつないでいます。

なおBMP280ではSDA,SCLをpullupせずに動作しています。

　　　XIAO ESP32S3と温度センサBMP280の配線

ブレッドボードには載せないので，XIAO ESP32S3のピンを上向きに付けています。
　　　XIAO ESP32S3と温度センサBMP280

プログラムの概要
central（windowsPCなど）からのリクエストで，PeripheralであるXIAO ESP32S3は，温度センサBMP280の値を取得し，centralに返します。
具体的には，XIAO ESP32S3はcentral（windowsPCなど）から文字列"start"を受け取ったら1秒間隔で温度などのデータをcentralに送信し，文字列"stop"を受け取ったら送信をやめるようにします。

説明
BLE UART通信ですが，やりたいことは，BMP280の値を取得し送信することですので，BLEの煩雑な部分は，クラスHandy_BLE_Uartに任せて舞台裏に隠れてもらいます。
このプログラムでは受信時にやるべきことを記述した関数は，void StringReceptionReport(String str)としました。送られてくるstrが受信した文字列です。（受信時にやるべきことを記述した関数の名前は別のものでもOKです）
やるべきこととは，「start」「stop」によりブール変数「requested」のtrue falseを切り替えることです。
ESP32S3側が送信するときは，関数transferString()を使います。

#define DEVICENAME "UART-B0"
は自分の名前です。通信相手のwindowsPCなどから見つけてもらう名前です。初期化の時点で決定します。

このプログラムではBLE通信の面倒なところをクラスHandy_BLE_Uartにして別ファイルに書いています。

クラスHandy_BLE_Uartの定義は「Handy_BLE_Uart.h」と「Handy_BLE_Uart.cpp」に書かれています。
ダウンロード，解凍して次のプログラムコードBLE_uart_BMP280.inoと同じフォルダに入れてください。

　　Handy_BLE_Uartのダウンロード

フォルダBLE_uart_BMP280にプログラムBLE_uart_BMP280.ino，Handy_BLE_Uart.h，Handy_BLE_Uart.cppを入れたところを示します。そうすると，ArduinoIDEの画面の上部にそれぞれのファイル名が表示されるようになり，クリックするとArduinoIDEでファイルの中を見ることができます。

なお，ペアリング・ボンディングを要求したい場合は，プログラムBLE_uart_BMP280.inoの初期化のときに
bleuart.begin(DEVICENAME, true);
ではなく
bleuart.begin(DEVICENAME, true, 123456);
のように6桁のパスキーを追加します。（パスキーは必ず6桁の数です。）

Arduino IDEでコンパイルするときは，ライブラリ"Grove_-_Barometer_Sensor_BMP280"を予めIDEに追加しておいてください。

　　　BLE_uart_BMP280.inoのプログラムコード

//BLE_uart_BMP280.ino
//XIAO-ESP32S3

#include <Handy_BLE_Uart.h>
#include "Seeed_BMP280.h"

#define DEVICENAME "UART-B0"
#define INTERVAL 1000 //millisec

Handy_BLE_Uart bleuart;
BMP280 bmp280;

void setup() {
Serial.begin(115200);
delay(300);

//start BMP280
if(!bmp280.init()){
    Serial.println("Device bmp280 error!");
}

//受信時に呼び出されるコールバック関数の登録　必須
bleuart.setCallbackFunc(StringReceptionReport);
//接続時にCentralに送信するメッセージの設定　必要があったら
bleuart.setInitialMessage("send me 'start' or 'stop'");
//初期化（パスキーによるペアリングを行う場合は6桁（必ず6桁）のパスキーを付ける）
//引数：自分のデバイス名登録，受信文字列のエコーバックの有無，（パスキー）
bleuart.begin(DEVICENAME, true);
//bleuart.begin(DEVICENAME, true, 123456);
delay(1000);
}

bool requested = false;
bool justrequested = false;

void loop() {
static int currenttime = 0; //millisec
static int previoustime = 0; //millisec
if (bleuart.isConnected()) {
    //Centralに接続中の場合
    if (justrequested) {
      bleuart.transferString("tempreture[degC], pressure[hPa], altitude[m]");
      justrequested = false;
      previoustime = millis(); //elapsed time(ms)
    } else if (requested) {
      currenttime = millis(); //elapsed time(ms)
      if (INTERVAL <= currenttime - previoustime) {
        previoustime += INTERVAL;
        float tempreture = bmp280.getTemperature();
        float pressure = bmp280.getPressure();
        float altitude = bmp280.calcAltitude(pressure);
        char string0[256];
        sprintf(string0, "%.1f, %.0f, %.2f", tempreture, pressure/100.f, altitude);
        bleuart.transferString(String(string0));
      }
    }
} else {
    requested = false;
}
delay(1000);
}

//受信時に呼び出されるコールバック関数
void StringReceptionReport(String str) {
Serial.println("RX_Value = " + str);
if (str.indexOf("start") == 0) {
    requested = true;
    justrequested = true;
} else if (str.indexOf("stop") == 0) {
    requested = false;
    justrequested = false;
}
}

先にXiaoESP32S3に電源を与え，立ち上げておきます。

　　"BMP280が接続されたXIAO ESP32S3（紙のアンテナがついています。）

その後，その後，WindowsPCの"BLE_serial_terminal.exe"を立ち上げるとすぐにBruetoothLEデバイスをスキャンして選択リストに表示します。
ここでは，XiaoESP32S3のプログラムの
#define DEVICENAME "UART-B0"
でつけた名前"UART-B0"が見つかるのでこれをクリックして選択します。
見つからなかったら，ボタン"Scan BLE Dev"をクリックして，にBruetoothLEデバイスを再スキャンします。

　　BLE_serial_terminal　デバイス選択画面

選択したら，ボタンConnectをクリックします。connectedが表示されたら，通信準備完了です。
"Time Stamp"および"Local Echo"のオプションをONにしておくとよいでしょう。

"BLE_serial_terminal"から"start"を送信すると，1秒ごとにデータが送信されてきます。
受信した3つの数値は温度[℃]，気圧[hPa]，標高[m]を表しています。
"BLE_serial_terminal"から"stop"を送信すると，データ送信が止まります。
"BLE_serial_terminal"から"start"や"stop"を送信するときは，画面上部のテキストボックスに入力してボタンSendをタップします。

　　　　BLE_serial_terminal 通信画面

画面上の送受信データのファイルへの保存は，右上のボタン"Save Log"で出来ます。

マイコンXIAO ESP32S3とWindowsパソコンでBLE Uart通信し，Windowsパソコンからの指令によって温度などのデータをXIAO ESP32S3が送るプログラムを示しました。

XIAO ESP32S3側のプログラムでは，BLE通信の面倒なところは，クラスHandy_BLE_Uartに封入して，データ送信部分に専念したプログラムコードに集中できるようにしました。

この記事ではWindowsパソコンのアプリ"BLE_serial_terminal"を使いました。
AndroidデバイスにもiOSデバイスにも同様なアプリがあり，"BLE_serial_terminal"と同じ使い方ができます。
　　Androidデバイス版の解説
　　iOSデバイス版の解説

ESP32S3+温度センサBMP280とWindowsPCとのBLE Uart通信